Skip to main content

SAP GUI save password by using SAP User script VBS

Before SAP Logon 740 version, we can enable SAP GUI to save password in GUI shortcut.

Yes, just enable it from Windows registry editor. By starting the program regedit.exe
HKEY_CURRENT_USER\Software\SAP\SAPShortcut\Security\EnablePassword

Since SAP GUI 750, for security reasons, SAP has disabled this remember features. 
We can use VBS script to help us auto logon SAP.
SAP Auto logon script

'------------------------------------------------------------------
'- VBScript to start SAP Logon if process doesn't exists and connect
'- to an SAP system. The SAP Logon process is detected via WMI
'- (Windows Management Instrumentarium), also the termination.
'-----------------------------------------------------------------------
  '-Directives----------------------------------------------------------
    Option Explicit
  '-Variables-----------------------------------------------------------
    Dim SAPLogon, SAPLogonTitle
  'Please change your SAPLogonTitle 
    SAPLogon = "saplogon.exe" : SAPLogonTitle = "SAP Logon 770"
    Dim SysDescr, SysIP
    '-----------------------------------------------------------------
    'Sysdescr is the descripting in SAP GUI, or you cant use SysIP as connection string. Enable one.
    '-----------------------------------------------------------------
    'SysDescr = "xxxdev" 
    'SysIP = "/H/RouterIP/S/router port/H/application IP/S/port"
     SysIP = "/M/messageserver/S/messageserver port/G/message group"
  '-Function FindProcess------------------------------------------------
    Function FindProcess(ProcessName)
      '-Variables-------------------------------------------------------
        Dim WMIServ, Processes, Process
      FindProcess = False
      Set WMIServ = GetObject("winmgmts:{impersonationLevel=" & _
       "impersonate}!\\.\root\cimv2") 
      Set Processes = WMIServ.ExecQuery("Select * from Win32_Process " & _
        "Where Name = '" & ProcessName & "'")
      For Each Process In Processes
        FindProcess = True
        Exit Function
      Next
    End Function
  '-Sub TerminateProcess------------------------------------------------
    Sub TerminateProcess(ProcessName)
      '-Variables-------------------------------------------------------
      Dim WMIServ, Processes, Process
      Set WMIServ = GetObject("winmgmts:{impersonationLevel=" & _
        "impersonate}!\\.\root\cimv2") 
      Set Processes = WMIServ.ExecQuery("Select * from Win32_Process " & _
        "Where Name = '" & ProcessName & "'")
      For Each Process In Processes
        Process.Terminate()
        Exit Sub
      Next
    End Sub
  '-Function GetSAPGUIObject--------------------------------------------
  '- This function starts the SAP Logon if it is necessary and delivers
  '- its object
  '---------------------------------------------------------------------
    Function GetSAPGUIObject()
      '-Variables-------------------------------------------------------
        Dim WshShell, Exec
      If FindProcess(SAPLogon) Then
        Set GetSAPGUIObject = GetObject("SAPGUI")
      Else
        Set WshShell = CreateObject("WScript.Shell")
        Set Exec = WshShell.Exec(_
          "c:\Program Files (x86)\SAP\FrontEnd\SAPgui\" & SAPLogon)
        Do While Not WshShell.AppActivate(SAPLogonTitle) 
          WScript.Sleep 500 
        Loop
        Set GetSAPGUIObject = GetObject("SAPGUI")
      End If
    End Function
  '-Sub Main------------------------------------------------------------
    Sub Main()
      '-Variables-------------------------------------------------------
      Dim SapGuiAuto, Application, Connection, Session
      Set SapGuiAuto = GetSAPGUIObject()
      If Not IsObject(SapGuiAuto) Then
        Exit Sub
      End If
      Set Application = SapGuiAuto.GetScriptingEngine
      If Not IsObject(Application) Then
        Set SapGuiAuto = Nothing
        Exit Sub
      End If
      '-----------------------------------------------------------------
      '- You can choose user logon connection in SAP GUI or Connection String
      '-----------------------------------------------------------------
      'Set Connection = Application.OpenConnection(SysDescr, True)
      Set Connection = Application.OpenConnectionByConnectionString( SysIP, True)
      If Not IsObject(Connection) Then
        Set Application = Nothing
        Set SapGuiAuto = Nothing
        Exit Sub
      End If
      Set Session = Connection.Children(0)
      If Not IsObject(Session) Then
        Set Connection = Nothing
        Set Application = Nothing
        Set SapGuiAuto = Nothing
        Exit Sub
      End If
      MyScript(Session)
      'Set Session = Nothing
      'Set Connection = Nothing
      'Set Application = Nothing
      'Set SapGuiAuto = Nothing
      'TerminateProcess SAPLogon
    End Sub
  '-Sub MyScript--------------------------------------------------------
    Sub MyScript(Session)
      '-----------------------------------------------------------------
      '- Change your client, username and password
      '-----------------------------------------------------------------
      session.findById("wnd[0]").maximize
      session.findById("wnd[0]/usr/txtRSYST-MANDT").Text = "001"
      session.findById("wnd[0]/usr/txtRSYST-BNAME").text = "username"
      session.findById("wnd[0]/usr/pwdRSYST-BCODE").text = "password"
      session.findById("wnd[0]/usr/txtRSYST-LANGU").Text = "EN"
      session.findById("wnd[0]").sendVKey 0
    End Sub
  '-Main----------------------------------------------------------------
  Main


Labels:

Comments

Post a Comment

Popular posts from this blog

MMPV_DATE_CHECK: Error occurred (SAP Note 1082841) how to solve

SAP Note 1082841 - MMPV/Close Periods : Prevent shifting to a future period by mistake You must backup the database before executing following program or function in the Production system! Symptom When running MMPV/ Close Periods, prevent shifting to a future period by mistake (for example, a common mistake is running MMPV twice at the beginning of a month). Other Terms MMPV, MMPI, MARV, period roller, period shift, material ledger, MMPV_READ_NOTE, MMPV_DATE_CHECK, T001, PERIV Reason and Prerequisites In the event that MMPV is mistakenly executed twice at the beginning of a period, the active period could be shifted to a future period. As a consequence, system would accept goods movements with a posting date pointing to this wrong future period. To revert wrong period shift and correct such posting errors is difficult, especially when Material Ledger is active. Solution This note provides a feature to prevent using MMPV to shift into a future period.  The future period is defi...
Post a Comment
Read more

SAP How to mass close open sales orders (Partially or Not Executed)

Sometimes we need to mass close open sales orders (Partially or Not Executed). Using VA02 to close them one by one is inefficient. Method 1: You can use the TCODE MASS . Method 2: You can also use the  TCODE VKM4  to close all open orders. Firstlly use VA06 to choose what SO you wana to mass close, then copy the SO number to VKM4, and execute. Select all item and click Reject.
Post a Comment
Read more

S/4 HANA create or modify PO Error WY 163 - no contact person found

  Symptom You are creating purchase order (PO) and you get terminating message "Express document 'Update was canceled' when user releasing the document and hence output messages automatically processed due to dispatch time 4 settings, or you use dispatch time 3 and using ME9f for output sending. Or you are using S/4HANA Output Control with dispatch time 2 and the output ends in error or similar termination visible. Further details from canceled update in transaction SM13 shows message is from class WY with number 163 and text "no contact person found". Environment Materials Management (MM) SAP ERP Central Component SAP ERP SAP enhancement package for SAP ERP SAP enhancement package for SAP ERP, version for SAP HANA SAP S/4HANA Cause The causing part is the output processing program, very likely the standard SAPFM06P program or its unmodified custom copy, as it has checks about plant and assigned customer master nr.: The root cause is that for the PO's receivi...
Post a Comment
Read more

SAP Error message FPUIFB086: Could not start Layout Designer (see long text) Please read SAP Note 1121176

SAP Error message FPUIFB086: Could not start Layout Designer (see long text) It means SAP require to open Adobe LiveCycle Designer locally. But your PC do not install any version of Adobe LiveCycle Designer. Form SAP Note 1121176 is obsoleted, and LiveCycle Designer 8.0 is quite an old release and newer Windows operating systems are not supported (for example Windows 7/Windows 8). Please use Designer 9.8 (SAP note 1658830) or higher instead of Designer 8.0. SAP Note 1658830 Adobe LiveCycle Designer 9.8 - Installation Symptom You want to install Adobe LiveCycle Designer (LCD) 9.8 on your local computer or upgrade your existing installation. Other Terms Adobe Document Services, ADS, Adobe LiveCycle Designer, SAP Interactive Forms by Adobe, PDF form Reason and Prerequisites You can use Adobe LiveCycle Designer 9.8 with the following versions of Adobe Document Services (ADS): SAP NetWeaver 7.31 and higher For lower releases of SAP NetWeaver, see SAP Note 1317925. This describes the ret...
Post a Comment
Read more

Newest version of Adobe LiveCycle Designer 11.0 download

As SAP Note 1121176  descripts, Adobe LiveCycle Designer 8.0 is quite an old release and newer Windows operating systems are not supported (for example Windows 7/Windows 8). Please use Designer 9.8 (SAP note 1658830) or higher instead of Designer 8.0. The newest version of Adobe LiveCycle Designer is 11.0.  SAP release a patch at 17.07.2024. PL 28 for ADOBE LIVECYCLE DESIGNER 11.0 Adobe LiveCycle Designer 11.0 Click here to download. PL 28 for ADOBE LIVECYCLE DESIGNER 11.0 Click here to download.
Post a Comment
Read more